#compdef gigaset -P gigaset-v*

# or like this if "setopt complete_aliases":
#compdef gigaset -P gigaset*

local state cmds cridfiles ret=1

local dir=${words[(r)--dir=*]##--dir=}
if [[ -z $dir ]]; then
  integer dirind=${words[(i)--dir]}
  if (( dirind )); then
    dir=$words[dirind+1]
  fi
fi

if [[ -z $dir ]]; then
  # try to read directory from the alias
  # e.g. alias gigaset2='gigaset --dir /movies/gigaset/PVR --nowarnings'
  if [[ -n $aliases[$words[1]] ]]; then
    aliasstring=aliases[$words[1]]
    aliaswords=${(z)aliasstring}
    local dir=${aliaswords[(r)--dir=*]##--dir=}
    if [[ -z $dir ]]; then
      integer dirind=${aliaswords[(i)--dir]}
      if (( dirind )); then
        dir=$aliaswords[dirind+1]
      fi
    fi
  else
    # default directory
    dir="/data/movies/gigaset/PVR/"
  fi
fi

# -S: no option will be completed after a `--' appearing on its own on the line
_arguments -S \
   '(--help --usage *)'{--help,--usage}'[Hilfestellung anzeigen]' \
   '--version[Programmversion anzeigen]' \
   '--manpage[komplette Manpage aufrufen]' \
   '*--debug[Debugmodus aktivieren, mehrfach benutzbar]' \
   '(--dir --criddir)'{--dir=,--criddir=}'[Verzeichnis mit den Aufnahmen und crid-Dateien]:criddir:_path_files -/' \
   '--exportdir=[Verzeichnis für den TS-Export der Aufnahmen]:exportdir:_path_files -/' \
   '--cutdir=[Verzeichnis mit den fertig geschnittenen (noch nicht gemuxten) Filmen]:cutdir:_path_files -/' \
   '--mpgdir=[Verzeichnis mit den fertig geschnittenen und gemuxten MPG-Filmen]:mpgdir:_path_files -/' \
   '(--yes --ja)'{--yes,--ja}'[Keine Sicherheitsabfragen, immer ja antworten]' \
   '--nowarnings[Warnungen unterdrücken]' \
   '--neverdie[Fehlermeldungen ja, aber kein Abbruch]' \
   '(--dontdel --nodel)'{--dontdel,--nodel}'[Temporäre Dateien nicht löschen]' \
   '(--force --overwrite)'{--force,--overwrite}'[vorhandene Dateien überschreiben]' \
   '(--nocolor --nc)'{--nocolor,--nc}'[monochrome Ausgabe]' \
   '(--alang --audiolang)'{--alang=,--audiolang=}'[Audio-Sprache einstellen, z.B. -alang deu,fra]:alang:((deu\:deutsch fra\:français en\:english spa\:español it\:italiano ...\:mehrere_durch_Komma_getrennt))' \
   '--search=[Beschränkung auf Aufnahmen mit dem Suchstring]:string:' \
   '--commands[Liste aller Kommandos]' \
   '1: :->cmds' \
   '*: :->args'

# first try (lacking the nice descriptions)
#   ':cmds: compadd ${${(f)"$(gigaset --commands 2>/dev/null)"}%%[[:space:]]##--*}' \
#   '*:cridfiles: compadd ${${(f)"$(gigaset --nowarnings --dir=$dir oneliner 2>/dev/null)"}%%[[:space:]]##-*}'

# simple alternative: complete *.crid without calling gigaset
#   '*:cridfiles:_path_files -W $dir -g "*.crid"'

case $state in
  cmds)
    # Bsp: cmds=(dump:"Details anzeigen" dir:"Liste der Aufnahmen")
    cmds=( ${${(M)${(f)"$(gigaset --commands 2>/dev/null)"}:#* -- *}/(#b)(*[^ ]) #-- (*)/$match[1]:$match[2]})

    _describe -t commands "gigaset commands" cmds && ret=0
  ;;
  args)
    case $line[1] in
      check|test|timeshift)
        (( ret )) && _message 'no more arguments'
      ;;
      *)
        cridfiles=( ${${(M)${(f)"$(gigaset --nowarnings --dir=$dir oneliner 2>/dev/null)"}:#* -- *}/(#b)(*[^ ]) #-- (*)/$match[1]:$match[2]})

        _describe -t commands "gigaset cridfiles" cridfiles && ret=0
      ;;
    esac
  ;;
esac